我正在尝试交叉编译libftdi。当我运行Cmake时,我得到:

CMake Error: The following variables are used in this project, but they are set to NOTFOUND.
Please set them or make sure they are set and tested correctly in the CMake files:
LIBUSB_INCLUDE_DIR (ADVANCED)

我了解应该在libftdi根目录下的FindUSB1.cmake中设置LIBUSB_INCLUDE_DIR。但是,我不知道如何使FindUSB1.cmake查找已编译并放入/ opt / lib的libusb。这是默认文件:
# - Try to find the freetype library
# Once done this defines
#
#  LIBUSB_FOUND - system has libusb
#  LIBUSB_INCLUDE_DIR - the libusb include directory
#  LIBUSB_LIBRARIES - Link these to use libusb

# Copyright (c) 2006, 2008  Laurent Montel, <montel@kde.org>
#
# Redistribution and use is allowed according to the terms of the BSD license.
# For details see the accompanying COPYING-CMAKE-SCRIPTS file.


if (LIBUSB_INCLUDE_DIR AND LIBUSB_LIBRARIES)

  # in cache already
  set(LIBUSB_FOUND TRUE)

else (LIBUSB_INCLUDE_DIR AND LIBUSB_LIBRARIES)
  IF (NOT WIN32)
    # use pkg-config to get the directories and then use these values
    # in the FIND_PATH() and FIND_LIBRARY() calls

    find_package(PkgConfig)
    pkg_check_modules(PC_LIBUSB libusb-1.0)
  ENDIF(NOT WIN32)

  FIND_PATH(LIBUSB_INCLUDE_DIR libusb.h
    PATHS ${PC_LIBUSB_INCLUDEDIR} ${PC_LIBUSB_INCLUDE_DIRS})

  FIND_LIBRARY(LIBUSB_LIBRARIES NAMES usb-1.0
    PATHS ${PC_LIBUSB_LIBDIR} ${PC_LIBUSB_LIBRARY_DIRS})

  include(FindPackageHandleStandardArgs)
  FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBUSB DEFAULT_MSG LIBUSB_LIBRARIES LIBUSB_INCLUDE_DIR)

  MARK_AS_ADVANCED(LIBUSB_INCLUDE_DIR LIBUSB_LIBRARIES)

endif (LIBUSB_INCLUDE_DIR AND LIBUSB_LIBRARIES)

在/ opt / lib中,有一个目录pkconfig。在此目录中,有一个libusb-1.0.pc文件,我想可能与该问题有关。那么我应该如何让Cmake查找/opt/lib/libsub-1.0?

最佳答案

不幸的是,默认的查找脚本不是很强大。如果该库不在find_library搜索的one of the default directories中,则必须依靠 pkg-config 来告诉您该库的位置。

在(不太可能)事件也没有向pkg-config注册该库的情况下,您别无选择,只能在调用查找脚本之前手动设置PC_LIBUSB_LIBDIRPC_LIBUSB_INCLUDEDIR变量。可以从命令行(使用 -D parameter)或在随附的CMake脚本中(使用 set )完成此操作。

如果您愿意更改find​​脚本,请考虑将其他HINTS添加到find调用中以使其更加灵活。例如,使用环境变量作为提示是一种非常流行的机制,该机制也适用于非Unix平台。

FIND_PATH(LIBUSB_INCLUDE_DIR libusb.h
    HINTS $ENV{LIBUSB_ROOT}
    PATHS ${PC_LIBUSB_INCLUDEDIR} ${PC_LIBUSB_INCLUDE_DIRS}
    PATH_SUFFIXES include)

FIND_LIBRARY(LIBUSB_LIBRARIES NAMES usb-1.0
    HINTS $ENV{LIBUSB_ROOT}
    PATHS ${PC_LIBUSB_LIBDIR} ${PC_LIBUSB_LIBRARY_DIRS}
    PATH_SUFFIXES lib)

10-06 10:18
查看更多