我想将clang-tidy集成到我们的C和C++,基于CMake的项目中,该项目使用自定义GCC工具链进行编译。

我尝试按照this tutorial设置CMAKE_CXX_CLANG_TIDY。我还尝试通过将CMAKE_EXPORT_COMPILE_COMMANDS设置为ON并将run-clang-tidy.py指向其目录来生成编译数据库。

在这两种情况下,我都遇到(相同)一些可能与Clang和GCC之间的差异有关的错误:

  • Clang不支持在CMake文件中启用的某些警告标志,但GCC支持(例如-Wlogical-op)。由于编译器是GCC,因此文件可以正确构建,并且标志被写入编译数据库,但是clang-tidy提示它。
  • clang-tidy提示一些定义,并且功能不可用,即使代码可以很好地编译。例如,android-cloexec-open check建议使用O_CLOEXEC来提高安全性并强制关闭文件,但是尝试使用此定义会导致未定义的标识符错误(即使我们的GCC编译了代码)。
    作为未找到功能的示例,有clock_gettime

  • 我们的代码使用C11标准和C++ 14标准进行编译,而没有GNU扩展:
    set(CMAKE_C_STANDARD 11)
    set(CMAKE_CXX_STANDARD 14)
    
    set(CMAKE_C_EXTENSIONS OFF)
    set(CMAKE_CXX_EXTENSIONS OFF)
    

    定制工具链是一种交叉编译工具链,可在Linux上运行并编译为FreeBSD。
  • 是否有办法禁止CMake将某些标志传递给clang-tidy?我使用clang-tidy错误吗?
  • 我怀疑此问题与使用交叉编译工具链禁用GNU扩展以及一些功能测试宏有关,该宏未在Clang中默认定义,而是由GCC定义(例如_GNU_SOURCE/_POSIX_SOURCE)。如果是这种情况,我该如何检查?如果没有,我应该另外使用clang-tidy吗?

  • 编辑

    按照@ pablo285的要求,这是针对单个文件的2条警告,然后在我添加--warnings-as-errors=*时,构建停止:
    error: unknown warning option '-Wlogical-op' ; did you mean '-Wlong-long'? [clang-diagnostic-error]
    
    <file path>: error: use of undeclared identifier 'O_CLOEXEC' [clang-diagnostic-error]
    O_WRONLY | O_CLOEXEC
               ^
    

    我决定编写一个Python脚本来替换clang-tidy,从CMake接收命令行并对其进行编辑以修复各种错误。这是我尝试的命令行修改:
  • 删除所有clang编译标志
  • 这有助于解决第一个警告,因为现在我不传递clang不知道的标志。看来我无法配置CMake将不同的标志集传递给GCC和整洁,因此,如果有人熟悉该问题的某些解决方案,我将很高兴听到!
  • 我更改了传递给clang-tidy的包含目录
  • 正如文章中提到的,我使用了一个自定义工具链(交叉编译)。我使用this post和Python提取标准包含目录的列表,并将它们作为-isystem <dir>列表添加到标志列表中。我还添加了-nostdinc,以便clang-tidy不会尝试查看自己的 header ,而不是我的 header
  • 这有助于解决上述问题,因为现在在工具链的 header 中定义了诸如O_CLOEXEC之类的各种定义,但是由于我的工具链基于GCC,所以clang无法解析<type_traits> header ,其中包括对许多编译器内部函数
  • 的调用
  • 我不确定在这种情况下最好的方法是

  • @shycha:感谢您的提示,我将尝试禁用此特定检查,然后再次编辑此帖子

    最佳答案

    好的,我认为我有解决方案。经过几个晚上,我得以使它工作。

    一般来说,我这样编译

    rm -rf build
    mkdir build
    cd build
    cmake -C ../cmake-scripts/clang-tidy-all.cmake .. && make
    

    其中cmake-scripts目录包含:
    clang-tidy-all.cmake
    toolchain_arm_clang.cmake
    

    下面列出了两个重要文件。
    但是更重要的是,您需要如何进行编译。

    首先,通过toolchain_arm_clang.cmakeclang-tidy-all.cmake直接引用set(CMAKE_TOOLCHAIN_FILE ...)。但是,必须从建筑目录的角度进行引用,因此,如果您使用多个构建目录级别,例如:build/x86build/armbuild/darwin等,则必须相应地修改该路径。

    其次,set(CONFIG_SCRIPT_PRELOADED ...)的目的是确保配置脚本已预先加载,即cmake -C ../cmake-scripts/clang-tidy-all.cmake ..通常,您希望在CMakeLists.txt文件中的某处具有以下内容:
    message(STATUS "CONFIG_SCRIPT_PRELOADED: ${CONFIG_SCRIPT_PRELOADED}")
    if(NOT CONFIG_SCRIPT_PRELOADED)
        message(FATAL_ERROR "Run cmake -C /path/to/cmake.script to preload a config script!")
    endif()
    

    第三,在/lib/ld-musl-armhf.so.1中有一个硬编码的set(CMAKE_LINKER_ARM_COMPAT_STATIC ...);在我使用的开发盒上,它指向/lib/libc.so,因此可以确定改为使用/lib/libc.sh。我从来没有试过。

    第四,之所以使用set(CMAKE_C_LINK_EXECUTABLE ...)set(CMAKE_LINKER_ARM_COMPAT_STATIC ...)是因为CMake在检查编译器(即什至在运行make之前)提示某些链接问题。

    第五,我只编译C++代码,因此,如果您需要编译一些C,则可能还需要正确配置set(CMAKE_C_CREATE_SHARED_LIBRARY ...),但是我不知道是否有这样的配置选项。

    一般建议

    不要立即将其集成。首先使用一个库(最好是一个C++一个)测试一些简单的CMake项目并使它工作,然后添加第二个库,但是在C中,再次对其进行调整。并且只有在此之后,才将其合并到代码库中。

    工具链

    我将自定义工具链与GCC 8.3.0musl C库一起使用,因此某些文件的位置对于其他工具链可能会有所不同。

    自定义CMake

    某些变量(例如(已经提到)CONFIG_SCRIPT_PRELOADEDEXPORT_PACKAGE_TO_GLOBAL_REGISTRYDO_NOT_BUILD_TESTSDO_NOT_BUILD_BENCHMARKS而非通用CMake选项,即,我仅在自己的CMakeLists.txt中使用它们,因此可以放心地忽略它们。

    在每个*.cmake文件末尾未设置的变量(例如build_testextra_clang_tidy_unchecks_for_tests_only)不需要出现在项目的主CMakeLists.txt中。


    $ clang --version
    clang version 10.0.0 (https://github.com/llvm/llvm-project.git 4650b2f36949407ef25686440e3d65ac47709deb)
    Target: x86_64-unknown-linux-gnu
    Thread model: posix
    InstalledDir: /opt/local/bin
    

    文件
    clang-tidy-all.cmake:
    set(ALL_CXX_WARNING_FLAGS --all-warnings -Weverything -Wno-c++98-compat -Wno-c++98-c++11-compat -Wno-c++98-c++11-c++14-compat -Wno-padded -Wno-c++98-compat-pedantic)
    set(CXX_COMPILE_OPTIONS "-std=c++17;-O3;${ALL_CXX_WARNING_FLAGS}" CACHE INTERNAL "description")
    
    
    set(CMAKE_CROSSCOMPILING True)
    set(CMAKE_TOOLCHAIN_FILE "../cmake-scripts/toolchain_arm_clang.cmake" CACHE FILEPATH "CMake toolchain file")
    
    set(CONFIG_SCRIPT_PRELOADED true CACHE BOOL "Ensures that config script was preloaded")
    
    
    set(build_test False)
    
    if(build_test)
        message(STATUS "Using test mode clang-tidy checks!")
        set(extra_clang_tidy_unchecks_for_tests_only ",-google-readability-avoid-underscore-in-googletest-name,-cppcoreguidelines-avoid-magic-numbers,-cppcoreguidelines-special-member-functions")
    endif()
    
    set(CMAKE_CXX_CLANG_TIDY "clang-tidy;--enable-check-profile;--checks=-*,abseil-string-find-startswith,bugprone-*,cert-*,clang-analyzer-*,cppcoreguidelines-*,google-*,hicpp-*,llvm-*,misc-*,modernize-*,-modernize-use-trailing-return-type,performance-*,readability-*,-readability-static-definition-in-anonymous-namespace,-readability-simplify-boolean-expr,portability-*${extra_clang_tidy_unchecks_for_tests_only}" CACHE INTERNAL "clang-tidy")
    
    message(STATUS "build_test: ${build_test}")
    message(STATUS "extra_clang_tidy_unchecks_for_tests_only: ${extra_clang_tidy_unchecks_for_tests_only}")
    message(STATUS "CMAKE_CXX_CLANG_TIDY: ${CMAKE_CXX_CLANG_TIDY}")
    
    # We want to skip building tests when clang-tidy is run (it takes too much time and serves nothing)
    if(DEFINED CMAKE_CXX_CLANG_TIDY AND NOT build_test)
        set(DO_NOT_BUILD_TESTS true CACHE BOOL "Turns OFF building tests")
        set(DO_NOT_BUILD_BENCHMARKS true CACHE BOOL "Turns OFF building benchmarks")
    endif()
    
    
    
    unset(build_test)
    unset(extra_clang_tidy_unchecks_for_tests_only)
    set(EXPORT_PACKAGE_TO_GLOBAL_REGISTRY "OFF" CACHE INTERNAL "We don't export clang-tidy-all version to global register")
    
    toolchain_arm_clang.cmake:
    set(CMAKE_SYSTEM_NAME Linux)
    set(CMAKE_SYSTEM_VERSION 4.14.0)
    set(CMAKE_SYSTEM_PROCESSOR arm)
    
    
    set(gcc_version 8.3.0)
    set(x_tools "/opt/zynq/xtl")
    
    set(CMAKE_C_COMPILER "clang" CACHE INTERNAL STRING)
    set(CMAKE_CXX_COMPILER "clang++" CACHE INTERNAL STRING)
    set(CMAKE_RANLIB "llvm-ranlib" CACHE INTERNAL STRING)
    set(CMAKE_AR "llvm-ar" CACHE INTERNAL STRING)
    set(CMAKE_AS "llvm-as" CACHE INTERNAL STRING)
    set(CMAKE_LINKER "ld.lld" CACHE INTERNAL STRING)
    
    execute_process(
        COMMAND bash -c "dirname `whereis ${CMAKE_LINKER} | tr -s ' ' '\n' | grep ${CMAKE_LINKER}`"
        OUTPUT_VARIABLE cmake_linker_dir
    )
    string(REGEX REPLACE "\n$" "" cmake_linker_dir "${cmake_linker_dir}")
    set(cmake_linker_with_dir "${cmake_linker_dir}/${CMAKE_LINKER}" CACHE INTERNAL STRING)
    
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -iwithsysroot /include/c++/${gcc_version} -iwithsysroot /include/c++/${gcc_version}/arm-linux-musleabihf" CACHE INTERNAL STRING)
    
    
    set(CMAKE_SYSROOT ${x_tools}/arm-linux-musleabihf)
    set(CMAKE_FIND_ROOT_PATH ${x_tools}/arm-linux-musleabihf)
    set(CMAKE_INSTALL_PREFIX ${x_tools}/arm-linux-musleabihf)
    
    set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
    set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
    set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE BOTH)
    set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE NEVER)
    
    
    
    set(triple arm-linux-musleabihf)
    set(CMAKE_LIBRARY_ARCHITECTURE ${triple})
    set(CMAKE_C_COMPILER_TARGET ${triple})
    set(CMAKE_CXX_COMPILER_TARGET ${triple})
    
    
    set(lib_path_arm ${x_tools}/arm-linux-musleabihf/lib)
    
    ## Bootstrap library stuff:
    set(Scrt1_o ${lib_path_arm}/Scrt1.o)
    set(crti_o ${lib_path_arm}/crti.o)
    set(crtn_o ${lib_path_arm}/crtn.o)
    
    set(lib_path_gcc ${x_tools}/lib/gcc/${triple}/${gcc_version})
    set(crtbeginS_o ${lib_path_gcc}/crtbeginS.o)
    set(crtendS_o ${lib_path_gcc}/crtendS.o)
    
    
    # Clang as linker
    # --no-pie disable position independent executable, which is required when building
    # statically linked executables.
    set(CMAKE_CXX_LINK_EXECUTABLE "clang++ --target=${triple} -Wl,--no-pie --sysroot=${CMAKE_SYSROOT} ${CMAKE_CXX_FLAGS} -fuse-ld=${cmake_linker_with_dir} <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET> ")
    set(CMAKE_CXX_CREATE_SHARED_LIBRARY "clang++ -Wl, --target=${triple} --sysroot=${CMAKE_SYSROOT} ${CMAKE_CXX_FLAGS} -fuse-ld=${cmake_linker_with_dir} -shared <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET> ")
    #
    # Do not use CMAKE_CXX_CREATE_STATIC_LIBRARY -- it is created automatically
    # by cmake using ar and ranlib
    #
    #set(CMAKE_CXX_CREATE_STATIC_LIBRARY "clang++ -Wl,--no-pie,--no-export-dynamic,-v -v --target=${triple} --sysroot=${CMAKE_SYSROOT} ${CMAKE_CXX_FLAGS} -fuse-ld=ld.lld <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET> ")
    
    
    ## Linker as linker
    set(CMAKE_LINKER_ARM_COMPAT_STATIC "-pie -EL -z relro -X --hash-style=gnu --eh-frame-hdr -m armelf_linux_eabi -dynamic-linker /lib/ld-musl-armhf.so.1 ${Scrt1_o} ${crti_o} ${crtbeginS_o} -lstdc++ -lm -lgcc_s -lgcc -lc ${crtendS_o} ${crtn_o}")
    set(CMAKE_C_LINK_EXECUTABLE "${CMAKE_LINKER} ${CMAKE_LINKER_ARM_COMPAT_STATIC} <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET>")
    
    
    # Debian bug 708744(?)
    #include_directories("${CMAKE_SYSROOT}/usr/include/")
    #include_directories("${CMAKE_SYSROOT}/usr/include/c++/${gcc_version}")
    #include_directories("${CMAKE_SYSROOT}/usr/include/c++/${gcc_version}/${triple}")
    
    ## Clang workarounds:
    set(toolchain_lib_dir_0 "${CMAKE_SYSROOT}/lib")
    set(toolchain_lib_dir_1 "${CMAKE_SYSROOT}/../lib")
    set(toolchain_lib_dir_2 "${CMAKE_SYSROOT}/../lib/gcc/${triple}/${gcc_version}")
    set(CMAKE_TOOLCHAIN_LINK_FLAGS "-L${toolchain_lib_dir_0} -L${toolchain_lib_dir_1} -L${toolchain_lib_dir_2}")
    
    ## CMake workarounds
    set(CMAKE_EXE_LINKER_FLAGS ${CMAKE_TOOLCHAIN_LINK_FLAGS} CACHE INTERNAL "exe link flags")
    set(CMAKE_MODULE_LINKER_FLAGS ${CMAKE_TOOLCHAIN_LINK_FLAGS} CACHE INTERNAL "module link flags")
    set(CMAKE_SHARED_LINKER_FLAGS ${CMAKE_TOOLCHAIN_LINK_FLAGS} CACHE INTERNAL "shared link flags")
    
    
    
    unset(cmake_linker_with_dir)
    unset(cmake_linker_dir)
    

    07-24 09:46
    查看更多