perl - Pango:在梵文串中查找位置

我正在使用Pango排版梵文。
考虑由DEVANAGARI LETTER U，DEVANAGARI LETTER MA，DEVANAGARI SIGN VIRAMA，DEVANAGARI LETTER KA，DEVANAGARI LETTER NA，DEVANAGARI SIGN VIRAMA，DEVANAGARI LETTER CHA，DEVANAGARI VOWEL SIGN AU组成的字符串उम्कन्छौ。
排版此字符串时，我想知道of(CHA)的起点以放置视觉标记。

对于普通的字符串，我将使用前一部分的长度，即उम्कन्，但这在这里不起作用，因为您可以看到न्(一半न)与combines结合使用，因此结果略有不同。

涉及组合时，是否可以获取字母的正确起点？

我尝试使用index_to_pos()查询Pango布局，但这似乎在字节级别(而不是字符)上起作用。

这个小的Perl程序显示了问题。垂直线向右偏移。

use strict;
use warnings;
use utf8;
use Cairo;
use Pango;

my $surface = Cairo::PdfSurface->create ("out.pdf", 595, 842);
my $cr = Cairo::Context->create ($surface);
my $layout = Pango::Cairo::create_layout($cr);
my $font = Pango::FontDescription->from_string('Lohit Devanagari');
$layout->set_font_description($font);

# Two parts of the phrase. Phrase1 ends in न् (half न).
my $phrase1 = 'उम्कन्';
my $phrase2 = 'छौ';

# Set the first part of the phrase, and get its width.
$layout->set_markup($phrase1);
my $w = ($layout->get_size)[0]/1024;

# Set the complete phrase.
$layout->set_markup($phrase1.$phrase2);

my ($x, $y ) = ( 100, 100 );

# Show phrase.
$cr->move_to( $x, $y );
$cr->set_source_rgba( 0, 0, 0, 1 );
Pango::Cairo::show_layout($cr, $layout);

# Show marker at width.
$cr->set_line_width(0.25);
$cr->move_to( $x + $w, $y-10 );
$cr->line_to( $x + $w, $y+50 );
$cr->stroke;

$cr->show_page;

最佳答案

您无法测量局部渲染。取而代之的是测量整个渲染，并以字素方式遍历字符串以找到位置。另请参阅:https://gankra.github.io/blah/text-hates-you/#style-can-change-mid-ligature

use strict;
use warnings;
use utf8;
use Cairo;
use Pango;
use List::Util qw(uniq);
use Encode qw(encode);

my $surface = Cairo::PdfSurface->create('out.pdf', 595, 842);
my $cr = Cairo::Context->create ($surface);
my $layout = Pango::Cairo::create_layout($cr);
my $font = Pango::FontDescription->from_string('Lohit Devanagari');
$layout->set_font_description($font);
my $phrase = 'उम्कन्छौ';
my @octets = split '', encode 'UTF-8', $phrase; # index_to_pos operates on octets
$layout->set_markup($phrase);
my ($x, $y) = (100, 100);
$cr->move_to($x, $y);
$cr->set_source_rgba(0, 0, 0, 1);
Pango::Cairo::show_layout($cr, $layout);
$cr->set_line_width(0.25);
my @offsets = uniq map { $layout->index_to_pos($_)->{x}/1024 } 0..$#octets;
# (0, 9.859375, 16.09375, 27.796875, 33.953125, 49.1875)
for my $offset (@offsets) {
    $cr->move_to($x+$offset, $y-5);
    $cr->line_to($x+$offset, $y+25);
    $cr->stroke;
}
my @graphemes = $phrase =~ /\X/g; # qw(उ म् क न् छौ)
while (my ($idx, $g) = each @graphemes) {
    if ($g =~ /^छ/) {
        $cr->move_to($x+$offsets[$idx], $y-10);
        $cr->line_to($x+$offsets[$idx], $y+50);
        $cr->stroke;
        last;
    }
}
$cr->show_page;

关于perl - Pango:在梵文串中查找位置，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/58395294/