perl - 使用Hash::Merge将散列与数组合并

我正在尝试使用 Hash::Merge 合并包含一个或多个数组的两个哈希。例如:

use strict;
use warnings;
use feature qw(say);

use Data::Dump qw(dump);
use Hash::Merge qw(merge);

my $h1 = { a => [ { aa => 1 }, 3 ] };
my $h2 = { a => [ { bb => 2 } ] };

my $hLeft  = merge( $h1, $h2 );
my $hRight = merge( $h2, $h1 );

say "  hLeft: " . dump($hLeft);
say " hRight: " . dump($hRight);

my $hDesired = { a => [ { aa => 1, bb => 2 }, 3 ] };
say "Desired: " . dump($hDesired);

这给出了输出:

  hLeft: { a => [{ aa => 1 }, 3, { bb => 2 }] }
 hRight: { a => [{ bb => 2 }, { aa => 1 }, 3] }
Desired: { a => [{ aa => 1, bb => 2 }, 3] }

如何使用Hash::Merge获得正确的输出？

最佳答案

合并数组的默认行为是附加它们:

sub { [ @{$_[0]}, @{$_[1]} ] },

要获得不同的行为，必须使用 Hash::Merge::specify_behavior 。

以下解决方案是LEFT_PRECEDENT，并将数组元素合并到元素:

use strict;
use warnings;
use feature qw(say);

use Data::Dump qw(dump);
use Hash::Merge qw(merge);

Hash::Merge::specify_behavior(
    {   'SCALAR' => {
            'SCALAR' => sub { $_[0] },
            'ARRAY'  => sub { $_[0] },
            'HASH'   => sub { $_[0] },
        },
        'ARRAY' => {
            'SCALAR' => sub { [ @{ $_[0] }, $_[1] ] },
            'ARRAY'  => sub {
                my ( $left, $right ) = @_;

                my @merged = @$left;
                my @to_add = @$right;

                for (@merged) {
                    last if !@to_add;
                    $_ = Hash::Merge::merge( $_, shift @to_add );
                }

                return [ @merged, @to_add ];
            },
            'HASH'  => sub { [ @{ $_[0] }, values %{ $_[1] } ] },
        },
        'HASH' => {
            'SCALAR' => sub { $_[0] },
            'ARRAY'  => sub { $_[0] },
            'HASH'   => sub { Hash::Merge::_merge_hashes( $_[0], $_[1] ) },
        },
    },
    'My Behavior',
);

my $h1 = { a => [ { aa => 1 }, 3 ] };
my $h2 = { a => [ { bb => 2 } ] };

my $merged = merge( $h1, $h2 );
say "Merged: " . dump($merged);

输出:

Merged: { a => [{ aa => 1, bb => 2 }, 3] }

关于perl - 使用Hash::Merge将散列与数组合并，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/26547424/