qt - Qt Quick Controls 2和TableView

在Quick Controls 2.0应用程序中使用TableView可以吗？
这将要求同时具有两个进口：

import QtQuick.Controls 1.4
import QtQuick.Controls 2.0

我会出现副作用吗？

另一个相关的问题：TableView似乎属于Quick Controls 1.0集。是吗？这是否意味着如果可以使用TableView，那么可以在Quick Controls 2.0应用程序中使用所有Quick Controls 1.0控件吗？

最佳答案

虽然可以在同一应用程序中混合使用Qt Quick Controls 1和2，但最大的问题是Qt Quick Controls 1与Qt的自动高DPI缩放不兼容，而Qt Quick Controls 2则基于此。因此，运行将两者混合使用的应用程序可能无法在高DPI显示器上获得理想的结果。

鉴于Qt Quick Controls 1 TableView存在严重的性能问题，一种可能的替代方法是使用Qt Quick核心中的ListView作为代理，使用Row。使用Qt 5.9及更高版本，可以显式指定内容的宽度和轻拂方向，以便垂直ListView也可以水平轻拂。这是一个过于简单的多列列表示例，您可以使用最新的Qt 5.9 beta进行尝试：

import QtQuick 2.9
import QtQuick.Controls 2.2

ApplicationWindow {
    id: window
    width: 360
    height: 360
    visible: true

    ListView {
        id: listView
        anchors.fill: parent

        contentWidth: headerItem.width
        flickableDirection: Flickable.HorizontalAndVerticalFlick

        header: Row {
            spacing: 1
            function itemAt(index) { return repeater.itemAt(index) }
            Repeater {
                id: repeater
                model: ["Quisque", "Posuere", "Curabitur", "Vehicula", "Proin"]
                Label {
                    text: modelData
                    font.bold: true
                    font.pixelSize: 20
                    padding: 10
                    background: Rectangle { color: "silver" }
                }
            }
        }

        model: 100
        delegate: Column {
            id: delegate
            property int row: index
            Row {
                spacing: 1
                Repeater {
                    model: 5
                    ItemDelegate {
                        property int column: index
                        text: qsTr("%1x%2").arg(delegate.row).arg(column)
                        width: listView.headerItem.itemAt(column).width
                    }
                }
            }
            Rectangle {
                color: "silver"
                width: parent.width
                height: 1
            }
        }

        ScrollIndicator.horizontal: ScrollIndicator { }
        ScrollIndicator.vertical: ScrollIndicator { }
    }
}

当然，这种简化的多列列表不提供诸如可移动和可调整大小的列以及内置于旧式TableView类型的其他钟声之类的功能。另一方面，性能则处于完全不同的水平，因此，如果您要针对的是具有无限资源的计算机上运行的经典台式机环境以外的其他目标，则可能值得考虑。 ;）

QT

qt - Qt Quick Controls 2和TableView