wolfram-mathematica - Mathematica中的Collat​​z猜想

我是Mathematica的新手，正在尝试了解模式和规则。所以我尝试了以下方法:

A = {1,2,3,4}
一个//。 {x_？EvenQ-> x/2，x_？OddQ-> 3 x +1}

这是基于:http://en.wikipedia.org/wiki/Collatz_conjecture

这应该收敛，但是我得到的是:

ReplaceRepeated::rrlim:在{1,2,3,4}扫描65536次之后退出。 >>

请帮助我了解我在模式/规则中的错误。

问候

最佳答案

您编写此代码的方式不会终止，因此它最终会在1和4、2等之间交替出现。(所有递归描述最终都必须在某个地方到达最低点，并且您不包括在n=1处进行编码的情况)。

这有效:

ClearAll[collatz];
collatz[1] = 1;
collatz[n_ /; EvenQ[n]] := collatz[n/2]
collatz[n_ /; OddQ[n]] := collatz[3 n + 1]

尽管它没有列出中间结果。获得它们的便捷方法是

ClearAll[collatz];
collatz[1] = 1;
collatz[n_ /; EvenQ[n]] := (Sow[n]; collatz[n/2])
collatz[n_ /; OddQ[n]] := (Sow[n]; collatz[3 n + 1])
runcoll[n_] := Last@Last@Reap[collatz[n]]

runcoll[115]
(*
-> {115, 346, 173, 520, 260, 130, 65, 196, 98, 49, 148, 74, 37, 112, 56,
28, 14, 7, 22, 11, 34, 17, 52, 26, 13, 40, 20, 10, 5, 16, 8, 4, 2, 1}
*)

要么

colSeq[x_] := NestWhileList[
Which[
EvenQ[#], #/2,
True, 3*# + 1] &,
 x,
 # \[NotEqual] 1 &]

这样，例如

colSeq[115]
(*
-> {115, 346, 173, 520, 260, 130, 65, 196, 98, 49, 148, 74, 37, 112, 56,
28, 14, 7, 22, 11, 34, 17, 52, 26, 13, 40, 20, 10, 5, 16, 8, 4, 2, 1}
*)

顺便说一句，我可以想出的最快方法(我想我在某些欧拉项目中需要它)是

Clear@collatz;
collatz[1] := {1}
collatz[n_] := collatz[n] = If[
  EvenQ[n] && n > 0,
  {n}~Join~collatz[n/2],
  {n}~Join~collatz[3*n + 1]]

相比:

colSeq /@ Range[20000]; // Timing
(*
-> {6.87047, Null}
*)

而

Block[{$RecursionLimit = \[Infinity]},
  collatz /@ Range[20000];] // Timing
(*
-> {0.54443, Null}
*)

(我们需要增加递归限制以使其正常运行)。