delphi - 在TMemo中锁定文本的开头

我想要一个TMemo，它总是以'SELECT c_name FROM'字符串开头，并且我想将其锁定，以便用户无法在TMemo中删除或替换此字符串，他们将不得不在此字符串之后编写其文本。有人可以帮我吗？我尝试了onChange事件，但问题是用户可以单击TMemo的开头并在开头进行编辑。

我正在使用Delphi 6。

最佳答案

TMemo不能满足您的要求。它只是不支持这种功能的标准Win32 EDIT控件的薄包装。

您需要改用TRichEdit。它支持保护您所描述的文本。添加所需的文本后，使用TRichEdit.SelStart和TRichEdit.SelLength属性选择它，然后将TRichEdit.SelAttributes.Protected属性设置为true。如果用户尝试以任何方式修改受保护的文本，则默认情况下TRichEdit将拒绝修改（您可以使用TRichEdit.OnProtectChange事件将AllowChange参数设置为true来覆盖该决定）。例如：

RichEdit1.Text := 'SELECT c_name FROM ';
RichEdit1.SelStart := 0;
RichEdit1.SelLength := 19;
RichEdit1.SelAttributes.Protected := True;

更新：默认情况下，保护文本还可以防止用户复制文本。如果希望用户能够复制受保护的文本，则必须显式启用它。尽管TRichEdit具有OnProtectChange事件以允许访问受保护的文本，但它不会告诉您为什么该文本正在请求访问。但是，基础EN_PROTECTED通知会这样做。因此，可以将TRichEdit子类化以直接截取EN_PROTECTED，然后仅在用户复制受保护的文本时才返回0（允许访问）。

interface

uses
  ...;

type
  TMyForm = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    DefRichEditWndProc: TWndMethod;
    procedure RichEditWndProc(var Message: TMessage);
  public
    { Public declarations }
  end;

...

implementation

uses
  Richedit;

procedure TMyForm.FormCreate(Sender: TObject);
begin
  DefRichEditWndProc := RichEdit1.WindowProc;
  RichEdit1.WindowProc := RichEditWndProc;

  RichEdit1.Text := 'SELECT c_name FROM ';
  RichEdit1.SelStart := 0;
  RichEdit1.SelLength := 19;
  RichEdit1.SelAttributes.Protected := True;
end;

procedure TMyForm.RichEditWndProc(var Message: TMessage);
begin
  DefRichEditWndProc(Message);
  if Message.Msg = CN_NOTIFY then
  begin
    if TWMNotify(Message).NMHdr.code = EN_PROTECTED then
    begin
      if PENProtected(Message.lParam).Msg = WM_COPY then
        Message.Result := 0;
    end;
  end;
end;

或者：

interface

uses
  ...;

type
  TRichEdit = class(ComCtrls.TRichEdit)
  private
    procedure CNNotify(var Message: TWMNotify); message CN_NOTIFY;
  end;

  TMyForm = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

...

implementation

uses
  Richedit;

procedure TMyForm.FormCreate(Sender: TObject);
begin
  RichEdit1.Text := 'SELECT c_name FROM ';
  RichEdit1.SelStart := 0;
  RichEdit1.SelLength := 19;
  RichEdit1.SelAttributes.Protected := True;
end;

procedure TRichEdit.CNNotify(var Message: TWMNotify);
begin
  inherited;
  if Message.NMHdr.code = EN_PROTECTED then
  begin
    if PENProtected(Message.NMHdr).Msg = WM_COPY then
      Message.Result := 0;
  end;
end;