我已经有答案了,但是我想了解为什么会起作用,但我不确定。

我有一个充满匹配项的以下变量:

 <xsl:variable name="invalid_characters" as="xs:string*">
   <xsl:analyze-string select="$urlToValidate" regex="{$regex}">
     <xsl:matching-substring>
       <xsl:value-of select="."/>
     </xsl:matching-substring>
   </xsl:analyze-string>
 </xsl:variable>

然后,我希望模板对该变量做一些处理,以防它不为null或为空,所以我这样问:
<xsl:if test="not($invalid_characters='')">
   <error>The error</error>
</xsl:if>

问题是,if始终为真...即使变量为空,我也必须像这样工作
<xsl:if test="$invalid_characters!=''">
   <error>The error</error>
</xsl:if>

让我困扰的是,如果我做这样的事情:
<xsl:if test="$invalid_characters=''">
   <error>The error</error>
</xsl:if>

if语句应做的事,因此,有人知道为什么我首先做的事不起作用吗?

提前致谢 :)

---编辑:有人说这个问题很难理解,所以我举一个例子。

在这里,您可以看到带有两个if语句和输入的xslt的完整示例。

xsl:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">

<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/">
    <xsl:apply-templates select="//@*"/>
</xsl:template>

<xsl:template match="@href[not(../scope) or     ../scope='local']|@conref|@conrefend">
    <xsl:variable name="urlToValidate" select="if(substring-before(.,'#')='')
                                     then .
                                     else substring-before(.,'#')"/>
    <xsl:variable name="regex">[\$&apos;%\*\./=\\&lt;&gt;_\(\)\[\]:;,\^~\?|@!\+&amp;\}\{]</xsl:variable>
    <xsl:variable name="invalid_characters" as="xs:string*">
        <xsl:analyze-string select="$urlToValidate" regex="{$regex}">
            <xsl:matching-substring>
                <xsl:value-of select="."/>
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:variable>
    <xsl:if test="not($invalid_characters='')">
        <error1>
            <xsl:value-of select="."/>
        </error1>
    </xsl:if>
    <xsl:if test="$invalid_characters!=''">
        <error2>
            <xsl:value-of select="."/>
        </error2>
    </xsl:if>
</xsl:template>
</xsl:stylesheet>

这是输入:
<links>
<image conrefend="GUID-6A680D85-10FA-4BCC-B57D-B5138ABE6A59" />
<image conrefend="GUID-1F14088D-4376-46FF-AE6F-937C2AAF5A43" />
<image conrefend="GUID-BB4F234D-3584-4B92-B9CB-D91FBD913B8D#GUID-BB4F234D-584-4B92-B9CB-D91FBD913B8D/MSCPDR1" />
<image conrefend="GUID-6E03D2D4-3FA9-4437-8689-06B873FB56CB" />
<image conrefend="GUID-C97E0253-73C1-4A27-B43E-7A913400BBB8" />
<image conrefend="COPY-GUI'D-86241639-37CD-4CF7-A7AA-F09F4A763944"/>
<image conrefend="COPY-GUID-86241639-37CD-4CF7-A7AA-F09F4A763944"/>
<image conref="COPY-GUID/*+-862416}39-37CD-4CF7-A7AA-F09F4A763944" />
<image conrefend="COPY-GUID-8624163{9-37CD-4CF7-A7AA-F09F4A763944"/>
<image href="COPY-GUID-8624163&lt;9-37CD-4CF7-A7AA-F09F4A763944" scope="local"/>
<image href="COPY-GUID-8624163~9-37CD-4CF7-A7AA-F09F4A763944" scope="local"/>
</links>

这是我得到的结果:
<error1>GUID-6A680D85-10FA-4BCC-B57D-B5138ABE6A59</error1>
<error1>GUID-1F14088D-4376-46FF-AE6F-937C2AAF5A43</error1>
<error1>GUID-BB4F234D-3584-4B92-B9CB-D91FBD913B8D#GUID-BB4F234D-3584-4B92-B9CB-D91FBD913B8D/MSCPDR1</error1>
<error1>GUID-6E03D2D4-3FA9-4437-8689-06B873FB56CB</error1>
<error1>GUID-C97E0253-73C1-4A27-B43E-7A913400BBB8</error1>
<error1>COPY-GUI'D-86241639-37CD-4CF7-A7AA-F09F4A763944</error1>
<error2>COPY-GUI'D-86241639-37CD-4CF7-A7AA-F09F4A763944</error2>
<error1>COPY-GUID-86241639-37CD-4CF7-A7AA-F09F4A763944</error1>
<error1>COPY-GUID/*+-862416}39-37CD-4CF7-A7AA-F09F4A763944</error1>
<error2>COPY-GUID/*+-862416}39-37CD-4CF7-A7AA-F09F4A763944</error2>
<error1>COPY-GUID-8624163{9-37CD-4CF7-A7AA-F09F4A763944</error1>
<error2>COPY-GUID-8624163{9-37CD-4CF7-A7AA-F09F4A763944</error2>
<error1>COPY-GUID-8624163&lt;9-37CD-4CF7-A7AA-F09F4A763944</error1>
<error2>COPY-GUID-8624163&lt;9-37CD-4CF7-A7AA-F09F4A763944</error2>
<error1>COPY-GUID-8624163~9-37CD-4CF7-A7AA-F09F4A763944</error1>
<error2>COPY-GUID-8624163~9-37CD-4CF7-A7AA-F09F4A763944</error2>

如您所见,每个条目都有一个error1标签,而只有应有的情况才有一个error2标签。

关于为什么第一次比较无法按我认为的方式工作的任何想法?

最佳答案

您的变量是一个序列,它包含零个,一个或多个字符串(每个字符串是否可以为空或取决于特定的正则表达式)。

空序列和空字符串之间的比较:

空序列和空字符串是不同的东西。空序列和空字符串之间的比较总是返回false:

() = ''    false
() != ''   false

单项序列和空字符串之间的比较:

包含单个字符串的序列与该字符串等效(请参见XPath Data Model),因此它可以是空字符串,也可以(或)不同于空字符串:
('') = ''      true
('') != ''     false

('foo') = ''   false
('foo') != ''  true

多项目序列和空字符串之间的比较:

如果两个序列至少具有相同的项目,则它们为“相等”,如果至少具有不同的项目,则为“不同”。因此,两个序列可以相等也可以不同。

比较多项目序列和字符串时,这也适用,因为我们已经看到,字符串等效于仅包含该字符串的序列:
('', '') = ''           true
('', '') != ''          false

('foo', 'bar') = ''     false
('foo', 'bar') != ''    true

('foo', '') = ''        true
('foo', '') != ''       true

结论:

在处理序列时,检查$a != $b 不等同于检查not($a = $b)

09-10 07:49
查看更多