java - Gradle:如何将单 jar 输出用作launch4j的输入

我想创建一个exe文件，而不必在exe旁边放置所有必需的库。
以前，我是用ant创建的，带有一个jar的自包含jar文件，然后使用launch4j将其包装到exe文件中。

Gradle既有插件，又有独立插件，两者几乎都不需要配置即可很好地工作。

但是，如何管理将创建的一个jar用作launch4j的输入？

这是我当前的构建文件:

apply plugin: 'java'
apply plugin: 'launch4j'
apply plugin: 'gradle-one-jar'

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'edu.sc.seis.gradle:launch4j:1.0.6'
        classpath 'com.github.rholder:gradle-one-jar:1.0.4'
    }
}

launch4j {
    mainClassName = "de.my.umkopierer.Umkopierer"
    launch4jCmd = "C:/Program Files (x86)/Launch4j/launch4j"
    jar = "lib/Umkopierer-1.0.jar"
    headerType = "console"
    dontWrapJar = false
}

sourceCompatibility = 1.7
version = '1.0'

jar {
    manifest {
        attributes 'Implementation-Title': 'Umkopierer', 'Implementation-Version': version
    }
}

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'commons-collections', name: 'commons-collections', version: '3.2'
    compile 'com.google.guava:guava:18.0'
    compile 'com.fasterxml.jackson.core:jackson-core:2.4.4'
    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jdk7:2.4.4'
    compile 'com.fasterxml.jackson.core:jackson-databind:2.4.4'


    testCompile group: 'junit', name: 'junit', version: '4.+'
}

task oneJar(type: OneJar) {
    mainClass = "de.stiffi.umkopierer.Umkopierer"
}

最佳答案

我通过使launch4j任务'createExe'依赖于onejar / fatjar(或任何其他胖 jar 创建方法)解决了这一问题。例如。:

tasks.createExe.dependsOn('oneJar')


task launch4j(overwrite: true, dependsOn: ['createExe']){
}

我也认为您的gradle构建文件应包含一个主类属性，例如

manifest {
    attributes 'Main-Class':'com.example.MyMainClass'
}

(至少在使用fatjar gradle插件的情况下就是这种情况)。