执行以下代码时,Delphi XE3 Update 2出现内部编译错误:

unit Unit1;

interface

type
  IHasValueR<T> = interface
    function GetValue: T;
  end;

  IHasValueRw<T> = interface(IHasValueR<T>)
    procedure SetValue(NewValue: T);
  end;
  TDummy = class(TInterfacedObject)

  end;

  TRefObj = class(TInterfacedObject, IHasValueR<Boolean>, IHasValueRw<Boolean>)
  strict private
    Value: Boolean;
  public
    constructor Create(Init_: Boolean);
    function GetValue: Boolean;
    procedure SetValue(NewValue: Boolean);
  end;

  TValueProviderFct<T, V> = reference to function(Input: T): V;

  TBar<T; V: IHasValueRw<Boolean>> = class
  strict private
    FValueProviderFct: TValueProviderFct<T, V>;
  public
    constructor Create(ValueProviderFct_: TValueProviderFct<T, V>);
    function GetValue(Input: T): Boolean;
  end;

procedure TestIt();

implementation

procedure TestIt();
var
  Foo: TRefObj;
  Bar: TBar<TRefObj, IHasValueRw<Boolean>>;
begin
  Foo := TRefObj.Create(true);

  Bar := TBar<TRefObj, IHasValueRw<Boolean>>.Create(
    function (Input: TRefObj): IHasValueRw<Boolean>
    begin
      Result := Input;
    end
  );
  Bar.GetValue(Foo);
end;

{ TSetupDefinitionItemBoolean }

constructor TRefObj.Create(Init_: Boolean);
begin
  Value := Init_;
end;

function TRefObj.GetValue: Boolean;
begin
  Result := Value;
end;

procedure TRefObj.SetValue(NewValue: Boolean);
begin
  Value := NewValue;
end;

{ TBar<T, V> }

constructor TBar<T, V>.Create(ValueProviderFct_: TValueProviderFct<T, V>);
begin
  FValueProviderFct := ValueProviderFct_;
end;

function TBar<T, V>.GetValue;
begin
  Result := FValueProviderFct(Input).GetValue;
end;

end.


错误信息:


[dcc32致命错误] Unit1.pas(83):F2084内部错误:C13823


解决方案只是将GUID添加到接口。

谁能验证?
它可能已经在较新的Delphi版本中修复了吗?
我们在哪里可以提交错误报告?

最佳答案

谁能验证?它可能已经在较新的Delphi版本中修复了吗?


作为记录:
这在Delphi XE4中已修复。

它在XE2中也可以正常编译,因此它似乎特定于您的版本。


我们在哪里可以提交错误报告?


http://qc.embarcadero.com/wc/qcmain.aspx

10-07 19:09
查看更多