excel - 使用msoFileDialogFilePicker保存

我已经在该主题上进行了很多搜索，并且尝试了很多事情。实际上，我需要让用户保存为msoFileDialogSaveAs过滤器中不可用的自定义类型。

我知道我可以另存为*.txt，然后在保存前更改扩展名。我这样做是可行的，但是当用户在已经包含自定义类型的其他文件的文件夹中输入文件名时，用户将看不到现有的自定义文件列表，因为事件过滤器不是该类型的。

因此，我想知道是否存在一种通过键入文件名来使用msoFileDialogFilePicker保存为自定义类型的方法。

这是可能的样子:

Function userFileSaveDialog_OneFilterOnly(iFilter As String, _
                                    iExtension As String, _
                                    Optional iTitle As String)

    With Application.FileDialog(msoFileDialogFilePicker) '(msoFileDialogSaveAs)
        .Filters.Clear
        .Filters.Add iFilter, iExtension
        .AllowMultiSelect=False
        .ButtonName "Save"
        .Title = iTitle
        If CBool(.Show) Then
            userFileSaveDialog_OneFilterOnly = .SelectedItems(.SelectedItems.Count)
        Else
        End If
    End With

End Function

谢谢您的帮助!

最佳答案

就像我在评论中提到的那样，您可以使用Application.GetSaveAsFilename
语法是
expression.GetSaveAsFilename(InitialFilename, FileFilter, FilterIndex, Title, ButtonText)
这是一个使用它的例子

Sub Sample()
    Dim Ret

    Ret = userFileSaveDialog_OneFilterOnly("My Special Files", "Sid", "An Example")

    MsgBox Ret
End Sub

Function userFileSaveDialog_OneFilterOnly(iFilter As String, _
                                          iExtension As String, _
                                          Optional iTitle As String)
    Dim Ret

    Ret = Application.GetSaveAsFilename(fileFilter:=iFilter & _
                                                    " (*." & _
                                                    iExtension & _
                                                    "), *." & iExtension, _
                                                    Title:=iTitle)

    If Ret <> False Then userFileSaveDialog_OneFilterOnly = Ret
End Function

实际操作中