sql - 如何不插入具有空值的双记录

我试图找到一种方法，仅在表中不存在新记录时才插入。

这是存储过程：

USE [ABSTest]
GO
/****** Object:  StoredProcedure [dbo].[sp_InsertBudgetCommessaInPreventivo]    Script     Date: 01/07/2013 09:12:16 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author:      <Alex Ziani>
-- Create date: <04/01/2013>
-- Description: <Insert di valori con inserimento di parametri>
-- =============================================
ALTER PROCEDURE [dbo].[sp_InsertBudgetCommessaInPreventivo]
@Progressivo                    nvarchar(50),
@Durata                         float,
@Costo                          money,
@CostoStandard                  money,
@Tariffa                        money,
@SpeseStandard                  money,
@Codice_Tipo                    nvarchar(50),
@Codice_FiguraProfessionale     nvarchar(10),
@Codice_Risorsa                 nvarchar(50),
@Codice_Commessa                nvarchar(20),
@Codice_ODL                     nvarchar(30),
@Task                           nvarchar(100)

AS
BEGIN
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON;

IF NOT EXISTS   (SELECT * FROM Preventivo WHERE Progressivo = @Progressivo
            AND Quantita = @Durata
            AND Costo = @Costo
            AND CostoStandard = @CostoStandard
            AND Tariffa = @Tariffa
            AND SpeseStandard = @SpeseStandard
            AND FkCodiceEnumTipoPreventivo = @Codice_Tipo
            AND FkCodiceEnumFiguraProfessionale = @Codice_FiguraProfessionale
            AND FKCodiceRisorsa = @Codice_Risorsa
            AND FkCodiceCommessa = @Codice_Commessa
            AND FkCodiceOrdineDiLavoro = @Codice_ODL
            AND Task = @Task)
BEGIN
    INSERT INTO [ABSTest].[dbo].[Preventivo]
           ([Progressivo]
           ,[Quantita]
           ,[Costo]
           ,[CostoStandard]
           ,[Tariffa]
           ,[SpeseStandard]
           ,[FkCodiceEnumTipoPreventivo]
           ,[FkCodiceEnumFiguraProfessionale]
           ,[FKCodiceRisorsa]
           ,[FkCodiceCommessa]
           ,[FkCodiceOrdineDiLavoro]
           ,[Task])
     VALUES
           (@Progressivo
           ,@Durata
           ,@Costo
           ,@CostoStandard
           ,@Tariffa
           ,@SpeseStandard
           ,@Codice_Tipo
           ,@Codice_FiguraProfessionale
           ,@Codice_Risorsa
           ,@Codice_Commessa
           ,@Codice_ODL
           ,@Task)
 END
 ELSE
 BEGIN
    RAISERROR 50001 'ERRORE: RECORD GIà PRESENTE'
 END
END

这可以正常工作，但是所有值（主键除外）都是Nullable，因此如果我将Null值作为参数，它将无法正常工作。我该如何设计它同时与Null一起使用？

最佳答案

您可以使用以下代码进行检查：

IF NOT EXISTS   (SELECT * FROM Preventivo WHERE ISNULL(Progressivo,'') = ISNULL(@Progressivo,'')
        AND ISNULL(Quantita,0) = ISNULL(@Durata,0)
        AND ISNULL(Costo,0) = ISNULL(@Costo,0)
        AND ISNULL(CostoStandard,0) = ISNULL(@CostoStandard,0)
        AND ISNULL(Tariffa,0) = ISNULL(@Tariffa,0)
        AND ISNULL(SpeseStandard,0) = ISNULL(@SpeseStandard,0)
        AND ISNULL(FkCodiceEnumTipoPreventivo,'') = ISNULL(@Codice_Tipo,'')
        AND ISNULL(FkCodiceEnumFiguraProfessionale,'') = ISNULL(@Codice_FiguraProfessionale,'')
        AND ISNULL(FKCodiceRisorsa,'') = ISNULL(@Codice_Risorsa,'')
        AND ISNULL(FkCodiceCommessa,'') = ISNULL(@Codice_Commessa,'')
        AND ISNULL(FkCodiceOrdineDiLavoro,'') = ISNULL(@Codice_ODL,'')
        AND ISNULL(Task,'') = ISNULL(@Task,'') )