javascript - 从页面源获取个人资料ID

我想查找用户的Facebook个人资料ID。我在php和excel中做了大量的google搜索，但没有成功。
如。
如果我转到https://www.facebook.com/zuck，在源代码中，我看到“profile_id”：4。这里4是马克·扎克伯格的个人资料ID。同样的，我需要识别一些人的个人资料ID，我已经准备好了他们的Facebook网址。最好的方法是什么？php、excel、javascript或任何其他语言。
请帮我一个开始，因为我已经挣扎了两天了。
谢谢
编辑：
在excel中我做了这样的事情

Sub find()

Dim ie As Object
    Set ie = CreateObject("InternetExplorer.Application")
    With ie
        ie.Visible = False
        ie.Navigate "http://findfacebookid.com/"
    ie.Visible = True

    Do While ie.Busy
        Application.StatusBar = "Downloading information, lease wait..."
        DoEvents
    Loop

    pro = ie.Document.getElementsByID("profile_id")
End With


End Sub

最佳答案

免责声明：我不知道php，也不使用Facebook Apis。这些方法很有可能给你提供更好的东西
下面是一个示例代码，它将在不到2秒的时间内为您提供ID。下面是Excel-VBA中的一个代码，我在几个配置文件链接（包括我的）上进行了测试，它成功了。

Option Explicit

Sub Sample()
    Dim sURL As String
    Dim webSource As String
    Dim tmpString As String

    sURL = "https://www.facebook.com/zuck"

    With CreateObject("Microsoft.XMLHTTP")
        .Open "GET", sURL, False
        .send
        webSource = .responsetext
    End With

    tmpString = Split(webSource, "profile_id=")(1)
    tmpString = Split(tmpString, "&")(0)

    Debug.Print tmpString '<~~ Gives 4
End Sub

如果您有一个URL列表，那么您可以将其保存在记事本或Excel区域中。没关系。确保读取数组中的所有数据，然后将其用于循环。
评论跟进
我尝试了两种方法，如果我保持在循环中，它只对第一个id有效，而对下一个id无效。如果我保持在循环之外，那么如何从.open命令打开surl？我所做的是，对于r=1到150，surl=range（“a”&r）。值，最后是下一个r。你能编辑代码并告诉我正确的方法吗？–塞卜哈27秒前
我已经对代码发表了评论，但如果您仍然有问题，只需问：）

Option Explicit

Sub Sample()
    Dim sURL As String
    Dim webSource As String, tmpString As String
    Dim i As Long, lRow As Long
    Dim ws As Worksheet

    '~~> This is the worksheet which has ids.
    Set ws = ThisWorkbook.Sheets("Sheet2")

    With ws
        '~~> Assuming that the urls are in Col A
        '~~> Find last row of col A
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row

        With CreateObject("Microsoft.XMLHTTP")
            For i = 1 To lRow
                sURL = ws.Range("A" & i).Value
                .Open "GET", sURL, False
                .send

                webSource = .responseText

                If InStr(1, webSource, "profile_id=") Then
                    tmpString = Split(webSource, "profile_id=")(1)
                    tmpString = Split(tmpString, ",")(0)
                ElseIf InStr(1, webSource, "profile_id"":") Then
                    tmpString = Split(webSource, "profile_id"":")(1)
                    tmpString = Split(tmpString, ",")(0)
                End If
                '~~> The ids will be written to Col B
                If tmpString <> "" Then ws.Range("B" & i).Value = tmpString
            Next i
        End With
    End With
End Sub