[转]NSIS：使用SectionSetFlags根据不同环境自动勾选特定区段

转自： http://www.flighty.cn/html/bushu/20140526_232.html

 

在微软SQL2000+SP4集成安装版安装包中可以根据目标操作系统自动勾选对应的版本，有同学问我这个功能是如何实现的，今天轻狂写一个短文统一回复一下。

 

重点就是使用了SectionSetFlags指令，以下是NSIS 用户手册中的说明：

 

设置区段标记。标记为 32 位整数。第一位(低位)代表该区段当前是否选中，第二位代表该区段是否是一个区段组 (请不要修改这里除非你真的很了解), 第三位代表该区段是否是一个区段组的结尾 (同样，请不要修改)，第四位代表该区段文字是否描黑显示，第五位代表该区段是否是只读，第六位代表区段组是否自动展开，第七位代表区段组是部分选定的，第八位是部分选定区段组切换内部使用，第九位是用来反映区段名称更改。如果指定了超出范围的区段则会放置一个错误的标记。

每个标记名称都以 `SF_` 开头:

 

!define SF_SELECTED   1

!define SF_SECGRP     2

!define SF_SECGRPEND  4

!define SF_BOLD       8

!define SF_RO         16

!define SF_EXPAND     32

!define SF_PSELECTED  64

 

我们只用第一位即可。

 

下面是完整脚本：

;少轻狂www.nsisfans.com

Name "根据不同环境自动勾选特定区段"

OutFile "根据不同环境自动勾选特定区段.exe"

!include "MUI2.nsh"

!include "WinVer.nsh"

!insertmacro MUI_PAGE_COMPONENTS

!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese"

InstallDir "$TEMP"

Section /o "SQL2000开发版" SEC01

  SectionIn RO

  MessageBox MB_OK|MB_ICONEXCLAMATION '开发版！'

SectionEnd

Section /o "SQL2000企业版" SEC02

  SectionIn RO

  MessageBox MB_OK|MB_ICONEXCLAMATION '企业版！'

SectionEnd

Function .onInit

${If} ${IsServerOS}

  SectionGetFlags ${SEC02} $R0

  IntOp $0 $R0 | ${SF_SELECTED}

  SectionSetFlags ${SEC02} $0

${Else}

  SectionGetFlags ${SEC01} $R0

  IntOp $0 $R0 | ${SF_SELECTED}

  SectionSetFlags ${SEC01} $0

${EndIf}

FunctionEnd

另：在onInit当然不局限于判断操作系统，而是可以根据指定的特征，比如判断注册表键值或者某文件是否存在等。轻狂在这里只是提一个思路，具体就看大家怎么发挥了。

轻狂志（少轻狂）原创文章，转载请注明作者和出处，谢谢！

http://www.flighty.cn/html/bushu/20140526_232.html