Arduino 字符串 | Arduino 教程

字符串用于存储文本。它们可用在LCD或Arduino IDE串口监视器窗口中显示文本。字符串也可用于存储用户输入。例如，用户在连接到Arduino的键盘上键入的字符。

在Arduino编程中有两种类型的字符串：

字符数组，与C编程中使用的字符串相同。
Arduino字符串，它允许我们在草图中使用字符串对象。

在本章中，我们将学习Arduino草图中的字符串，对象和字符串的使用。在本章末尾，你将学习在草图中使用哪种类型的字符串。

字符串字符数组

我们要学习的第一种类型的字符串是 char 类型的一系列字符。在前面的章节中，我们学习了一个数组是什么：存储器中存储的相同类型的变量的连续序列。一个字符串是一个char变量的数组。

字符串是一个特殊的数组，在字符串的末尾有一个额外的元素，其值总是为0（零）。这被称为“空终止字符串”。

字符串字符数组示例

此示例将显示如何创建字符串并将其打印到串口监视器窗口。

例

void setup() {
   char my_str[6]; // an array big enough for a 5 character string
   Serial.begin(9600);
   my_str[0] = 'H'; // the string consists of 5 characters
   my_str[1] = 'e';
   my_str[2] = 'l';
   my_str[3] = 'l';
   my_str[4] = 'o';
   my_str[5] = 0; // 6th array element is a null terminator
   Serial.println(my_str);
}

void loop() {

}

以下示例显示了字符串由什么组成。一个具有可打印字符的字符数组和0作为数组的最后一个元素，表示这是字符串结束的位置。通过使用 Serial.println()并传递字符串的名称，可以将字符串打印到Arduino IDE串口监视器窗口。

同样的例子可以用更方便的方式编写，如下所示：

示例

void setup() {
   char my_str[] = "Hello";
   Serial.begin(9600);
   Serial.println(my_str);
}

void loop() {

}

在这个草图中，编译器计算字符串数组的大小，并自动使用空值0终止字符串。一个长度为六个元素长，由五个字符后跟一个零组成的数组，其创建方式与上一个草图完全相同。

操作字符串数组

我们可以在草图中更改字符串数组，如下图所示。

例子

void setup() {
   char like[] = "I like coffee and cake"; // create a string
   Serial.begin(9600);
   // (1) print the string
   Serial.println(like);
   // (2) delete part of the string
   like[13] = 0;
   Serial.println(like);
   // (3) substitute a word into the string
   like[13] = ' '; // replace the null terminator with a space
   like[18] = 't'; // insert the new word
   like[19] = 'e';
   like[20] = 'a';
   like[21] = 0; // terminate the string
   Serial.println(like);
}

void loop() {

}

结果

I like coffee and cake
I like coffee
I like coffee and tea

以上草图按以下方式工作。

（1）创建和打印字符串

在上面给出的草图中，创建了一个新的字符串，然后打印出来显示在串口监视器窗口中。

（2）缩短字符串

通过用空终止0替换字符串中的第14个字符来缩短字符串。这是从0开始计算的字符串数组中的13号元素。

打印字符串时，所有字符都打印到新的空终止0。其他字符不消失；它们仍然存在于内存中，并且字符串数组仍然是相同的大小。唯一的区别是任何使用字符串的函数只能看到第一个空终止符前的字符串。

（3）更改字符串中的单词

最后，草图用“tea”代替“cake”一词。它首先必须用空格替换空终止符，如[13]，以便将字符串恢复为原来的格式。

新字符用单词“tea”覆盖单词“cake”的“cak”。这是通过覆盖单个字符来完成的。“cake”的“e”被替换为新的空终止字符。结果是字符串实际上终止于两个空字符，即字符串末尾的原始字符，以及替换“cake”中的“e”的新字符。这在打印新字符串时没有区别，因为打印字符串的函数在遇到第一个空终止字符时将停止打印字符串字符。

操作字符串数组的函数

上一个草图通过访问字符串中的单个字符，以手动方式操作字符串。为了更方便操作字符串数组，你可以编写自己的函数来执行，也可以使用 C 语言库中的一些字符串函数。

下面显示了操作字符串数组的列表函数。

S.No。	功能＆amp; 描述
1	String() String类是版本0019的核心部分，允许您以比字符数组更复杂的方式使用和操作文本字符串。您可以连接字符串，附加到它们，搜索和替换子字符串等。它比一个简单的字符数组占用更多的内存，但它也更有用。作为参考，字符数组被称为具有小“s"的字符串，String类的实例被称为具有大写字母S的字符串。注意，“双引号"中指定的常量字符串被视为char数组，不是String类的实例
2	charAt() 访问字符串的特定字符。
3	compareTo() 比较两个字符串，测试一个是在另一个之前还是之后，或者它们是否相等。字符串使用字符的ASCII值逐字符比较。这意味着，例如，\'a\'在\'b\'之前但在\'A\'之后。数字在字母之前。
4	concat() 将参数附加到字符串。
5	c_str() 将字符串的内容转换为C样式的以null结尾的字符串。请注意，这可以直接访问内部String缓冲区，应谨慎使用。特别是，你不应该通过返回的指针修改字符串。当您修改String对象或者它被销毁时，由c_str()先前返回的任何指针将变得无效，不应该再使用。
6	endsWith() 测试String是否以另一个字符串的字符结尾。
7	equals() 比较两个字符串的相等性。比较是区分大小写的，意味着字符串“hello"不等于字符串“HELLO"。
8	equalsIgnoreCase() 比较两个字符串的相等性。比较不区分大小写，意味着String(“hello")等于字符串(“HELLO")。
9	getBytes() 将字符串的字符复制到提供的缓冲区。
10	indexOf() 在另一个字符串中查找字符或字符串。默认情况下，它从字符串的开始搜索，但也可以从给定的索引开始，允许找到字符或字符串的所有实例。
11	lastIndexOf() 在另一个字符串中查找字符或字符串。默认情况下，它从字符串的结尾搜索，但也可以从给定的索引向后工作，允许定位字符或字符串的所有实例。
12	length() 返回字符串的长度，以字符为单位。 (请注意，这不包括尾随的空字符。)
13	remove() 修改就地，字符串从提供的索引中删除字符到字符串的结尾或从提供的索引到索引加计数。
14	replace() String replace()函数允许您用另一个字符替换给定字符的所有实例。您还可以使用replace用不同的子字符串替换字符串的子字符串。
15	reserve() String reserve()函数允许您在内存中分配一个用于操作字符串的缓冲区。
16	setCharAt() 设置String的字符。对现有长度以外的索引没有影响。
17	startsWith() 测试字符串是否以另一个字符串的字符开头。
18	toCharArray() 将字符串的字符复制到提供的缓冲区。
19	substring() 获取字符串的子字符串。起始索引是包含性的(相应的字符包含在子字符串中)，但可选的结束索引是排它的(相应的字符不包括在子字符串中)。如果省略结束索引，子字符串将继续到字符串的结尾。
20	toInt() 将有效的字符串转换为整数。输入字符串应以整数开始。如果字符串包含非整数，函数将停止执行转换。
21	到Float() 将有效的字符串转换为浮点型。输入字符串应以数字开头。如果字符串包含非数字字符，则函数将停止执行转换。例如，字符串“123.45"，“123"和“123fish"分别转换为123.45,123.00和123.00。注意，“123.456"近似为123.46。还要注意，浮点数只有6-7个十进制数字的精度，更长的字符串可能会被截断。
22	toLowerCase() 获取字符串的小写版本。从1.0开始，toLowerCase()修改字符串到位，而不是返回一个新的。
23	toUpperCase() 获取字符串的大写版本。从1.0开始，toUpperCase()修改字符串，而不是返回一个新的。
24	trim() 获取一个版本的字符串，删除任何前导和尾随空格。从1.0开始，trim()修改字符串，而不是返回一个新的。

下一个草图使用了一些C字符串函数。

例子

void setup() {
   char str[] = "This is my string"; // create a string
   char out_str[40]; // output from string functions placed here
   int num; // general purpose integer
   Serial.begin(9600);

   // (1) print the string
   Serial.println(str);

   // (2) get the length of the string (excludes null terminator)
   num = strlen(str);
   Serial.print("String length is: ");
   Serial.println(num);

   // (3) get the length of the array (includes null terminator)
   num = sizeof(str); // sizeof() is not a C string function
   Serial.print("Size of the array: ");
   Serial.println(num);

   // (4) copy a string
   strcpy(out_str, str);
   Serial.println(out_str);

   // (5) add a string to the end of a string (append)
   strcat(out_str, " sketch.");
   Serial.println(out_str);
   num = strlen(out_str);
   Serial.print("String length is: ");
   Serial.println(num);
   num = sizeof(out_str);
   Serial.print("Size of the array out_str[]: ");
   Serial.println(num);
}

void loop() {

}

结果

This is my string
String length is: 17
Size of the array: 18
This is my string
This is my string sketch.
String length is: 25
Size of the array out_str[]: 40

以上草图按以下方式工作。

（1）打印字符串

最新创建的字符串将打印到串口监视器窗口，如之前的草图所完成的。

（2）获取字符串的长度

strlen()函数用于获取字符串的长度。字符串的长度仅对于可打印字符，不包括空终止符。

该字符串包含17个字符，因此我们在串口监视器窗口中看到17个字符。

（3）获取数组的长度

运算符sizeof()用于获取包含字符串的数组的长度。长度包括空终止符，因此长度比字符串的长度多1。

sizeof()看起来像一个函数，但技术上是一个运算符。它不是C字符串库的一部分，但在草图中用于显示数组大小和字符串大小（或字符串长度）之间的差异。

（4）复制字符串

strcpy()函数用于将str[]字符串复制到out_num[]数组。strcpy()函数将传递给它的第二个字符串复制到第一个字符串中。现在，字符串的副本存在于out_num[]数组中，但只占用了数组的18个元素，因此在数组中仍然有22个空闲的char元素。这些空闲元素在内存中的字符串的后面可以找到。

将字符串复制到数组中，以便我们在数组中有一些额外的空间用于草图的下一部分，即在字符串的末尾添加一个字符串。

（5）将字符串附加到字符串（连接）

草图将一个字符串加到另一个字符串，这称为串联。这是使用strcat()函数完成的。strcat()函数将传递给它的第二个字符串放到传递给它的第一个字符串的末尾。

串联后，打印字符串的长度以显示新的字符串长度。然后打印数组的长度，以显示在40个元素长的数组中有一个25个字符长度的字符串。

请记住，25个字符长度的字符串实际上占用了数组的26个字符，因为还有空终止0。

数组边界

使用字符串和数组时，在字符串或数组的边界内工作是非常重要的。在示例草图中，创建了一个长度为40个字符的数组，以分配可用于操作字符串的内存。

如果数组太小，而我们尝试复制比数组大的字符串，那么字符串将复制到超出数组的末尾。超出数组末尾的内存可能包含草图中使用的其他重要数据，然而它们将被字符串覆盖。如果超出字符串末尾的内存超出范围，则可能会导致草图崩溃或导致意外行为。